Working with DataSets

This chapter is from the book

Sams Teach Yourself ADO.NET in 21 Days

Learn More Buy

This chapter is from the book

This chapter is from the book 

Sams Teach Yourself ADO.NET in 21 Days

Learn More Buy

Using a DataView

The final common technique used to work with a DataSet is to display its data using a DataView. Simply put, a DataView object is a view of a particular DataTable within a DataSet that can expose the data in a particular sort order or can filter the data. In other words, you can use a DataView to create a filtered and sorted view of a DataTable and then bind that view to a Windows or Web Forms control by referencing the DataView in the control's DataSource property. Unlike the Select statement discussed earlier, the DataView doesn't create copies of the rows, but is dynamic in that all changes to the underlying DataTable are immediately reflected in the DataView.

The important members of the DataView class are shown in Table 3.3.

Table 3.3 Important DataView Members

Creating a DataView

A DataView can be created either by instantiating a new DataView object and using its overloaded constructor, or by creating a reference to the view exposed by the DefaultView property of the DataTable object.

In the first case, the constructor is overloaded to accept the DataTable from which to create the view and, optionally, the sort order, row filter, and row state filter used to sort and populate the view. For example, the following code snippet creates a DataView that contains all the unchanged titles written by an author, sorted by title:

Dim books As DataSet
Dim dt As DataTable

books = GetTitles("Sams")
dt = dsBooks.Tables(0)

Dim dv As New DataView(dt, "Author = 'Fox, Dan'", _
 "Title ASC", DataViewRowState.Unchanged)

The last line of code above could also have been rewritten as follows:

dv = books.Tables(0).DefaultView

With dv
 .Sort = "Title ASC"
 .RowFilter = "Author = 'Fox, Dan'"
 .RowStateFilter = DataViewRowState.Unchanged
End With

In both cases, the resulting DataView is now ready to be used.

Sorting and Filtering

As is obvious from the preceding code snippets, the Sort, RowFilter, and RowStateFilter properties control how a DataView is sorted and filtered. It should be noted that the Sort property is of type String and can be set to multiple columns in order to create a multi-level sort. For example, to sort on Price and PubDate, you could use the following expression:

dv.Sort = "Price DESC, PubDate ASC"

When the Sort property is set, the DataView builds an index that is then used to display the data in sorted order. You'll also note from Table 3.3 that the DataView object exposes an ApplyDefaultSort property. This property can be set to True when the Sort property is set to an empty string or Nothing (null). It will reset the Sort property to sort by the value of the primary key if one is defined. Conversely, if the Sort property is already set, or a primary key hasn't been defined on the underlying DataTable, setting the property has no effect.

The RowFilter property is used in much the same way as the Select method of the DataTable object discussed previously. In fact, the expression syntax shown in Table 3.2 also applies to the RowFilter property. The RowStateFilter property can accept a bitwise combination of values from the DataViewRowState enumeration also discussed earlier.

Finding Rows

In addition to being able to filter the DataView based on the RowFilter property, you can also more quickly search the DataView using the index built when the Sort property is set using the Find and FindRows methods.

The Find method is overloaded to accept a single Object or array of objects that map to the columns defined in the Sort property. For example, if the Sort property is set as in the previous code snippet, the following code would return the index of the row that has a price of $44.99 and a PubDate of 11/16/2001:

Dim row As Integer

row = dv.Find(New Object() {44.99, CType("11/16/2001", Date)})

If the row is not found, a –1 is returned.

The FindRows method is analogous to Find in its signatures, but returns a one-element array populated with a DataRowView object in order to expose the row to Windows Forms as a control. You wouldn't typically call the FindRows method yourself.

Capturing Changes

Just as with the DataSet class, the DataView class exposes a single event, in this case, called ListChanged. This event is fired anytime the data or schema of the underlying DataTable changes, including changes in the sort order or filter applied to the view. The ListChangedEventArgs object from the System.ComponentModel namespace passed to the event handling method exposes the ListChangedType, NewIndex, and OldIndex properties, which encapsulate the reason why the event was fired, the new index of the item in the list, and the original index of the modified item, respectively.

As you might expect, the values in the NewIndex and OldIndex properties are populated based on the value of the ListChangedType property. The ListChangedType property returns one of the eight values of the ListChangedType enumeration. For example, if the ItemMoved value is specified, both the NewIndex and OldIndex properties will be populated, whereas if the ItemAdded value is specified, only the NewIndex property is set. The default for both properties when not set is –1.

In addition to standard ItemAdded, ItemDeleted, ItemChanged, and ItemMoved values, the ListChangedType property also includes PropertyDescriptorAdded, PropertyDescriptorChanged, PropertyDescriptorDeleted, and Reset values. The first three values in the preceding list are set when schema additions, changes, and deletions are made to the underlying DataTable. The Reset value is used when the Sort, RowState, or RowStateFilter properties of the DataView are set.

As an example, consider the code in Listing 3.8, which builds on the previous code that created the DataView object referred to as dv.

Listing 3.8 Detecting changes. This code hooks the ListChanged event and writes the ISBN of the modified row to the Trace object.

AddHandler dv.ListChanged, AddressOf TitlesChanged

Private Sub TitlesChanged(ByVal sender As Object, _
 ByVal e As ListChangedEventArgs)

 If e.ListChangedType = ListChangedType.ItemChanged Then
  Dim dv As DataView
  Dim dr As DataRow
  dv = CType(sender, DataView)
  dr = dv.Item(e.NewIndex).Row
  Trace.WriteLine("Changed ISBN: " & dr.Item("ISBN").ToString)
 End If
End Sub

Note that in Listing 3.8, the AddHandler statement is used to enable the ListChanged event handler using the ListChangedHandler delegate encapsulating the address of the TitlesChanged method. In this case, the TitlesChanged method uses the ListChangedType property to determine whether a row was changed and, if so, uses the sender argument and the NewIndex property to reference the row that was changed. The WriteLine method of the Trace class is then used to log the fact that a change occurred.

Managing Multiple Views

Because a DataSet can store data from multiple tables or data sources, it makes sense that you can also control the view settings (sort order and row filters) for each table in the DataSet. This is accomplished through the use of the DataViewManager class. The DataViewManager is primarily useful when you want to bind a DataSet with multiple tables to a control such as a grid to ensure that the grid displays each table correctly. Once again, you can populate the control's DataSource property with the DataViewManager object.

As with the DataView class itself, a DataViewManager object can be created in one of two ways. First, as you'll notice from Table 3.1, the DataSet exposes a DefaultViewManager property that points to a DataViewManager object that exposes a collection of DataViewSetting objects (DataViewSettingCollection) corresponding to each DataTable in the DataSet, as shown in Figure 3.2. By simply referencing the DefaultViewManager property, you are returned a DataViewManager object that contains DataViewSetting objects for each table. Second, you can instantiate your own DataViewManager, passing the DataSet into the constructor or populating its DataSet property.

Figure 3.2 The object hierarchy of the DataViewManager class. The DataViewManager object for a DataSet can be accessed through the DefaultViewManager property.

The DataViewSetting object exposes only a subset of the DataView members, including the ApplyDefaultSort, RowStateFilter, RowState, and Sort properties, along with properties that reference the underlying DataViewManager and Table. As a result, the DataViewSetting object is useful for changing the display characteristics of the underlying DataTable, but cannot be used to find rows or set the modification behavior. However, if the RowFilter, RowStateFilter, or Sort properties are changed in the DataViewSetting object, the corresponding properties in the DataView will also be set. This is the case because the DataViewSetting object simply reflects the values of the actual DataView.

As an example of using multiple views, consider the code snippet below. In this example, the DataSet dsOrders contains two tables that contain the Orders and OrderDetails information from the ComputeBooks database for a particular customer.

Dim orderV, orderDetV As DataViewSetting

orderV = orders.DefaultViewManager.DataViewSettings("Orders")
orderDetV = orders.DefaultViewManager.DataViewSettings("OrderDetails")

orderV.RowFilter = "OrderDate > #1/01/2002#"
orderDetV.Sort = "UnitPrice DESC"

In this case, the DefaultViewManager property of the DataSet object is used to access the DataViewSettingCollection in order to reference each DataViewSetting object. The DataViewSetting objects are then used to set the RowFilter property on the Orders table to display only the current year orders and sort the OrderDetails table by UnitPrice.

Optionally, the dvsOrder and dvsOrderDet objects could have been created independently, like so:

Dim dvm As New DataViewManager(dsOrders)

orderV = dvm.DataViewSettings("Orders")
orderDetV = dvm.DataViewSettings("OrderDetails")

In this case, the new DataViewManager object was passed the DataSet to create its collection on.