Adding Open Source 3D Physics to Your iOS Applications

Like this article? We recommend

Learning OpenGL ES for iOS: A Hands-on Guide to Modern 3D Graphics Programming

Learn More Buy

Like this article? We recommend

Like this article? We recommend 

Learning OpenGL ES for iOS: A Hands-on Guide to Modern 3D Graphics Programming

Learn More Buy

Using Bullet in Your iOS Application

All that remains is to build an application that actually uses Bullet and displays 3D objects. Apple's GLKit framework makes it relatively easy.

Make the view controller class generated by Xcode's Single View Application template into a subclass of GLKViewController instead of UIViewCintroller. The PViewController.h file in the tutorial sample code contains the following lines:

#import <GLKit/GLKit.h>
@interface PViewController : GLKViewController

Next, edit the MainStoryboard.storyboard file generated by Xcode's Single View Application template. Set the class of the generated view to GLKView using Xcode's Identity inspector, shown in Figure 12.

Figure 12 Setting the view's class to GLKView

Add the GLKit and OpenGLES frameworks to the project. The easiest way is to edit the project's Build Phases, as shown in Figure 13. Press the + button in the Link Binary with Libraries section to add frameworks.

Figure 13 GLKit and OpenGLES frameworks added to the project

If you build and run the tutorial project now, you should see a black screen. The next step is to create a physics simulation and draw something more interesting.

The tutorial source code includes a file named PAppDelegate.mm. The .mm extension tells Xcode to compile the file as Objective-C++ code intermixing C++ and Objective-C. The following code declares instance variables to store Bullet physics objects:

#import "PAppDelegate.h"
#include "btBulletDynamicsCommon.h"
#include <map>


typedef std::map<PPhysicsObject *, btCollisionObject*> 
   GModelShapeMap;


@interface PAppDelegate ()
{
   btDefaultCollisionConfiguration *collisionConfiguration;
   btCollisionDispatcher *dispatcher;
   btBroadphaseInterface *overlappingPairCache;
   btSequentialImpulseConstraintSolver *solver;
   btDiscreteDynamicsWorld *dynamicsWorld;
   btAlignedObjectArray<btCollisionShape*> collisionShapes;
   
   GModelShapeMap modelShapeMap;
}

@end

The GModelShapeMap modelShapeMap variable is used to store the relationships between Objective-C objects representing boxes and spheres and the corresponding shapes simulated by Bullet. A C++ map is a standard class similar in function to Cocoa Touch's NSDictionary class.

The physics simulation is initialized in PAppDelegate's -application:didFinishLaunchingWithOptions: method that's part of the Cocoa Touch standard application delegate protocol. The simulation is configured to use Earth's gravitational acceleration of -9.81 meters per second2. Comments explain the steps needed to initialize Bullet. Don't worry if it doesn't make much sense to you. It's boilerplate code.

/////////////////////////////////////////////////////////////////
// Creates needed physics simulation objects and configures
// properties such as the acceleration of gravity that seldom
// if ever change while the application executes.
- (BOOL)application:(UIApplication *)application 
   didFinishLaunchingWithOptions:(NSDictionary *)launchOptions
{
    ///collision configuration contains default setup for memory, 
   // collision setup. Advanced users can create their own 
   // configuration.
    collisionConfiguration = new 
      btDefaultCollisionConfiguration();
   
    ///use the default collision dispatcher. For parallel 
   // processing you can use a diffent dispatcher 
   // (see Extras/BulletMultiThreaded)
    dispatcher = new	  
      btCollisionDispatcher(collisionConfiguration);
   
    ///btDbvtBroadphase is a good general purpose broadphase. You 
   // can also try out btAxis3Sweep.
    overlappingPairCache = new btDbvtBroadphase();
   
    ///the default constraint solver. For parallel processing you 
   // can use a different solver (see Extras/BulletMultiThreaded)
    solver = new btSequentialImpulseConstraintSolver;
   
    dynamicsWorld = 
      new btDiscreteDynamicsWorld(
         dispatcher,
         overlappingPairCache,
         solver,
         collisionConfiguration);
   
    dynamicsWorld->setGravity(btVector3(0,-9.81,0));
   
   return YES;
}

PAppDelegate's -applicationWillTerminate: method tears down the simulation built in -application:didFinishLaunchingWithOptions:. It's not necessary to implement -applicationWillTerminate: in the tutorial sample code because when the application terminates, iOS will automatically reclaim the memory and other resources consumed by the physics engine. The code is provided in PAppDelegate.mm as example to follow if you ever need to clean up the physics engine while the application continues to execute.

PAppDelegate provides the following -physicsUpdateWithElapsedTime: method. Call the method periodically to give the physics engine opportunities to recalculate object positions and orientations.

/////////////////////////////////////////////////////////////////
// Turn the crank on the physics simulation to calculate 
// positions and orientations of collision shapes if
// necessary. The simulation performs up to 32 interpolation
// steps depending on the amount of elapsed time, and each step
// represents 1/120 seconds of elapsed time.
- (void)physicsUpdateWithElapsedTime:(NSTimeInterval)seconds;
{
   dynamicsWorld->stepSimulation(seconds, 32, 1/120.0f);
}

That's all it takes to start using Bullet physics for iOS. The simulation doesn't produce any interesting results unless some objects are added and set in motion to collide with each other. It's time to create, register, and draw physics objects.

GLKit provides most of the features needed. The tutorial project includes files named sphere.h and cube.h containing data declarations for 3D shapes. The data consists of vertex positions and "normal" vectors. Each shape is drawn as a list of connected triangles. The normal vectors provide information used to calculate how much simulated light reflects from each triangle.

The PViewController class implements all of the drawing for the tutorial. The drawing code is suboptimal to keep the code simple, and it turns out not to matter at run time. Profiling the tutorial code reveals that less than 20% of the application's execution time is spent drawing. Even if the drawing code is removed entirely, the application only runs 20% faster.

PViewController declares the following properties. The baseEffect property stores an instance of GLKit's GLKBaseEffect class. Modern GPUs are programmable allowing almost unlimited flexibility when rendering 3D graphics. The programs running on the GPU are sometimes called effects. GLKBaseEffect encapsulates the GPU programs needed by simple applications so that you don't need to dive into GPU programming when getting started.

@interface PViewController ()

@property (strong, nonatomic, readwrite)
   GLKBaseEffect *baseEffect;
@property (strong, nonatomic, readwrite) 
   NSMutableArray *boxPhysicsObjects;
@property (strong, nonatomic, readwrite) 
   NSMutableArray *spherePhysicsObjects;
@property (strong, nonatomic, readwrite) 
   NSMutableArray *immovableBoxPhysicsObjects;
   
@end

Other than baseEffect, the other properties all store arrays of Objective-C objects representing spheres and boxes in the simulation. Bullet only recalculates positions for physics objects that have mass. Objects created with zero mass are therefore immovable within the simulation. They don't become displaced when other objects collide or fall in response to gravity. The immovableBoxPhysicsObjects property stores an array of zero mass boxes used to form a floor. Without a few immovable objects in the simulation, all of the other objects would quickly fall out of view as the result of simulated gravity.

Two GLKViewController methods provide the key to drawing with GLKit: -update and -glkView:drawInRect:. The –update method is called periodically in sync with the iOS device display refresh rate. The display always refreshes 60 times per second, but GLKViewController's default behavior is to call –update at 30Hz. In other words, –update is called once for every two display refreshes. GLKViewController can be configured to call –update at other rates, but 30 times per second works well for simulations. Right after calling –update, GLKViewController tells the view it controls to display, and the view calls back to GLKViewController's -glkView:drawInRect:. Therefore, you implement simulation update in –update and implement custom 3D drawing code in -glkView:drawInRect:.

/////////////////////////////////////////////////////////////////
// This method is called automatically at the update rate of the 
// receiver (default 30 Hz). This method is implemented to
// update the physics simulation and remove any simulated objects
// that have fallen out of view.
- (void)update
{
   PAppDelegate *appDelegate = 
      [[UIApplication sharedApplication] delegate];
   
   [appDelegate physicsUpdateWithElapsedTime:
      self.timeSinceLastUpdate];

   // Remove objects that have fallen out of view from the 
   // physics simulation
   [self removeOutOfViewObjects];
}

The following drawing code sets baseEffect properties to match the orientation of the iOS device, specifies perspective, positions a light, and prepares for drawing 3D objects. The aspect ratio is the ratio of a view's width to its height. The aspect ratio may change when an iOS device is rotated from portrait orientation to landscape and back. Perspective defines how much of the 3D scene is visible at once and how objects in the distance appear smaller than objects up close.

In the real world, we only see objects that reflect light into our eyes. We perceive the shape of objects because different amounts of light reflect for different parts of the objects. Setting the baseEffect's light position controls how OpenGL calculates the amount of simulated light reflected off each part of a virtual 3D object. Calling [self.baseEffect prepareToDraw] tells the base effect to prepare a suitable GPU program for execution.

/////////////////////////////////////////////////////////////////
// GLKView delegate method: Called by the view controller's view
// whenever Cocoa Touch asks the view controller's view to
// draw itself. (In this case, render into a frame buffer that
// shares memory with a Core Animation Layer)
- (void)glkView:(GLKView *)view drawInRect:(CGRect)rect
{
   // Calculate the aspect ratio for the scene and setup a 
   // perspective projection
   const GLfloat  aspectRatio = 
   (GLfloat)view.drawableWidth / (GLfloat)view.drawableHeight;
   
   // Set the projection to match the aspect ratio
   self.baseEffect.transform.projectionMatrix = 
   GLKMatrix4MakePerspective(
      GLKMathDegreesToRadians(35.0f),// Standard field of view
      aspectRatio,
      0.2f,     // Don't make near plane too close
      200.0f); // Far arbitrarily far enough to contain scene
   
   // Configure a light
   self.baseEffect.light0.position = 
   GLKVector4Make(
      0.6f, 
      1.0f, 
      0.4f,  
      0.0f);// Directional light
      
   [self.baseEffect prepareToDraw];

   // Clear Frame Buffer (erase previous drawing)
   glClear(GL_COLOR_BUFFER_BIT|GL_DEPTH_BUFFER_BIT);
   
   [self drawPhysicsSphereObjects];
   [self drawPhysicsBoxObjects];      
}

OpenGL ES is a technology for controlling GPUs. Parts of OpenGL ES execute on the GPU itself, and other parts execute on the CPU. Programs call a library of C functions provided by OpenGL to tell OpenGL what to do. The glClear() function, called in the tutorial's -glkView:drawInRect:, erases previous drawing and discards previously calculated information about which 3D objects are in front of others.

PViewController's –drawPhysicsSphereObjects and –drawPhysicsBoxObjects methods draw spheres and boxes with positions and orientations calculated by the physics engine. Without going into a lot of detail, each of the methods calls OpenGL ES functions to specify where to find vertex data defining triangles. Then the triangles are drawn by calling code similar to the following:

      // Draw triangles using the first three vertices in the 
      // currently bound vertex buffer
      glDrawArrays(GL_TRIANGLES, 
         0,  // Start with first vertex in currently bound buffer
         sphereNumVerts);

OpenGL ES can only draw points, lines segments, and triangles. Complex shapes are composed of many triangles. The shapes in this tutorial are defined in sphere.h and cube.h. The shapes were initially drawn in a free open source 3D modeling application called Blender. Modeling is the term used by artists who create 3D shapes. The created models are exported from Blender in .obj file format and then converted into C header files suitable for direct use with OpenGL. Conversion is performed by an open source Perl language script.

It takes a little more work to setup GLKit. PViewController's -viewDidLoad method shows representative boilerplate code. This article glosses over methods like PViewController's –addRandomPhysicsObject. The code for adding physics objects is straightforward and particular to this tutorial. You'll most likely add different objects with different logic in your physics simulation projects.

Conclusion

The simulation provides remarkably complex and varied interaction between objects. The downloadable code is available in two variants. The Physics zip file (3dphyslibios_physics.zip) contains a Physics folder with an Xcode project. If you have built the Bullet demo applications for Mac OS X, you can copy the Physics folder into your bullet-2.80-rev2531 folder, double-click the Physics.xcodeproj file and press Run. A separate larger PhysicsPlusBullet zip file (3dphyslibios_physicsplusbullet.zip) contains the tutorial example and the needed Bullet source code combined. As always with open source, it's better to get the source code directly from the maintainers instead of grabbing a snapshot preserved in a tutorial's .zip file. Nevertheless, if you're impatient, the PhysicsPlusBullet zip file will get you up and running quickly.

This article provided a whirlwind tour of two large and powerful frameworks, Bullet and GLKit. It's not difficult to combine the two technologies in iOS applications. Like many open source libraries, Bullet is relatively easy to compile for iOS in spite of quirks related to the tools and coding style used by the library's authors. GLKit enables development of interesting and visually complex 3D applications with very little code. The tutorial implements all of its drawing in about 200 lines of code including comments and blank lines.

If you are interested in a more thorough introduction to 3D graphics concepts and GLKit, my new book, Learning OpenGL ES for iOS: A Hands-on Guide to Modern 3D Graphics Programming, is complete and available now as a Rough Cut electronic edition. Look for the title at your favorite bookstore in the fall. Free sample code from the book is available.