This chapter is from the book
This chapter is from the book
This chapter is from the book
The Sorting Table Stylesheet
Now that we have walked through the process of converting a ResultSet to a JDOM representation, it's time to take a look at the transforming stylesheet.
This XSL stylesheet is as generic as possible. In fact, it can be used to transform many different sets of data without altering anything. Any XML document that has grandchild elements with text data and child elements that group the grandchild elements can be output as a table with linked labels using this stylesheet.
The stylesheet has two root-level parameters. The first, Sort, is the column number by which to sort the resulting table. This parameter is used to enable the JSP to pass this sorting information through from the URL parameter. The value of the second parameter, Page, is used to create the links that will cause the re-sorting of the report.
The stylesheet is composed of three templates. The first template will match on the root element and begin the processing of the entire document. The next template will create all the table column labels, which are linked to cause the document to reload sorted on the chosen row. The last template will match each child of the root element in turn and output all element children as table cells.
The stylesheet begins with the XML document declaration, and root xsl:stylesheet element that describes the namespace of the XSL elements. The root level parameters are then declared void of default values, and the output method is set:
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:param name="Sort"/>
<xsl:param name="Page"/>
<xsl:output method="html" />
Next is the start of the first template. This template matches the root of the XML document with the match attribute value of /. This causes the entire XML document to pass into this template. The HTML div and table elements are output at this point, and the header template is called with an empty body through the call-template element. Then, the body of the header template is executed with the context node as the root of the document:
<xsl:template match="/">
<table border="1">
<xsl:call-template name="header"/>
Next, an apply-templates is used to select each element that matches the XPath statement */*. This statement will select each child element of the root in turn and match each to a template with a matching select attribute.
Notice that the body of this template tag is not empty. Inside, there is a sort element that selects which of a set of nodes to be sorted on. More specifically, this sort element selects the child whose position number is equal to the $Sort parameter by which to sort. This parameter-dependent statement enables us to dynamically sort the output. When these operations are completed, the end table HTML tag is output and the template is finished:
<xsl:apply-templates select="*/*">
<xsl:sort select="*[$Sort]" />
</xsl:apply-templates>
</table>
</xsl:template>
Let's look at the next template that creates the linked table labels. This again starts out by defining the template tag with the name attribute value of the header:
<!-- creates the table headers from the tag names --> <xsl:template name="header">
Next, a table row tag is output, followed by the beginning of a for-each loop. This loop selects each grandchild of the root element whose parent is first in the sibling position. This results in the exclusive selection in turn of each child that is descended from the first child of the root element. In other words, it selects each column of data one at a time from the first record of the ResultSet from which this XML descends:
<tr>
<xsl:for-each select="*/*[1]/*">
This causes the stylesheet to properly handle any number of data columns from the original ResultSet.
Within this loop, each link is created through the use of the appropriate text and stylesheet parameters. In this case, href is equal to the $Page variable set previously through the JSP, and the number of the data column in terms of sibling position returned by the position() method:
<th>
<A href="{$Page} ?sort={position()}">
In the preceding code snippet, the shorthand value-of notation is used—namely the curly brackets. This permits the inclusion of the results of XPath expressions within other output tags. If this feature were unavailable, the only way to access this information would be through the use of a value-of tag. This would make it impossible to dynamically create HTML element attribute values, because tags cannot contain other tags.
Now that the anchor element has been created with the proper href attribute value, the tag name of each element will be selected. This enables us to label the HTML table with each element's tag name regardless of the number of columns found in the original record set. This is achieved through the use of the local-name() method with the . parameter, which denotes this:
<xsl:value-of select="local-name(.)" />
Next, the anchor and table head cell is closed, as is the for-each loop that iterated through each element. The table row is closed and the template is complete:
</A>
</th>
</xsl:for-each>
</tr>
</xsl:template>
Last up is the template that will select each child element of the root, no matter how many, and output a table row formatted with cells for each text data containing child elements.
Like the previous template, this one iterates through each child of the root—except this one doesn't exclude all but the first child element. Once matched, a table row tag will be output, and a for-each element will iterate through each child element of the currently selected element through the *:
<!-- creates a row for each child of root, -->
<!-- and cell for each grandchild of root -->
<xsl:template match="*/*">
<tr>
<xsl:for-each select="*">
Next, the . notation is used to output the value of this, which will be each column of data found in one record. Finally, the table row is closed, and the template ended:
<td><xsl:value-of select="." /></td>
</xsl:for-each>
</tr>
</xsl:template>
Finally, the stylesheet root element is closed, and the document is finished. The complete stylesheet follows in Listing 11.6, and should be saved as \webapps\xmlbook\chapter11\TableSort.xsl.
Listing 11.6 TableSort.xsl
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:param name="Sort"/>
<xsl:param name="Page"/>
<xsl:output method="html" />
<xsl:template match="/">
<table border="1">
<xsl:call-template name="header"/>
<xsl:apply-templates select="*/*">
<xsl:sort select="*[$Sort]" />
</xsl:apply-templates>
</table>
</xsl:template>
<!-- creates the table headers from the tag names -->
<xsl:template name="header">
<tr>
<xsl:for-each select="*/*[1]/*">
<th>
<A href="{$Page} ?sort={position()}">
<xsl:value-of select="local-name(.)" />
</A>
</th>
</xsl:for-each>
</tr>
</xsl:template>
<!-- creates a row for each child of root, -->
<!-- and cell for each grandchild of root -->
<xsl:template match="*/*">
<tr>
<xsl:for-each select="*">
<td><xsl:value-of select="." /></td>
</xsl:for-each>
</tr>
</xsl:template>
</xsl:stylesheet>
The output of the previous Java class, JSP, and XSL stylesheet is as shown in Figure 11.1.
)
Figure 11.1. Results of DBtoXML.jsp, RStoXML.java, and TableSort.xsl.
If you encounter problems, verify that Xerces, Xalan, and JDOM have been installed. These examples depend on that software for successful execution.
Notice that the column heads are linked properly in order to cause the re-sorting of the document as shown, with the URL shown in the status bar. Also, the data is sorted on column number 1, as was set in the catch loop of parsing the query parameter in the JSP. To change this default value, just alter the parameter in the JSP.
This has been an example to demonstrate how easy it is to create a large number of reports. Simply by changing the data set that the stylesheet transforms, a large number of custom-arrangeable table reports can be created.