Sams Teach Yourself XML in 21 Days

Recommended Book

Sams Teach Yourself XML in 21 Days, 3rd Edition

Learn More Buy

Recommended Book

Recommended Book 

Sams Teach Yourself XML in 21 Days, 3rd Edition

Learn More Buy

Reading and Writing XML in .NET Code

Let's look at another example that shows how to work with XML in .NET programming. This time we'll use the XmlTextWriter and XmlTextReader classes. In this example, we'll use Visual Basic .NET code to write an XML document. We'll write out our sample document from Day 9, "Formatting XML by Using XSLT," which contains data on several states, and read it back in.

Begin by creating a new Windows project named ch21_02 and adding two buttons to it—Write XML Document and Read XML Document, as shown in Figure 21.15. Also add a multiline text box where we'll display the data we've read in, as shown in the figure.

Figure 21.15 Creating the ch21_02 project.

Next you need to use XmlTextWriter to write the XML.

Writing XML in .NET

To write your XML document with XmlTextWriter, you need to import System.Xml with an Imports statement to use this class. You will create a new object of the XmlTextWriter class, xwriter, and connect it to the XML document you'll create, data.xml:

Imports System.Xml
        .
        .
        .
Private Sub Button1_Click(ByVal sender As System.Object, _
    ByVal e As System.EventArgs) Handles Button1.Click
    Dim xwriter As New XmlTextWriter("data.xml", System.Text.Encoding.UTF8)
        .
        .
        .

Now use the various methods of the xwriter object to write your new XML document from code. You'll start with the WriteStartDocument method to start the new XML document. Then you'll use the WriteStartElement method to create the <states> document element, which you'll put in the "www.XMLPowerCorp.com" namespace. You'll also create the first <state> element by using WriteStartElement, like this:

Imports System.Xml
        .
        .
        .
Private Sub Button1_Click(ByVal sender As System.Object, _
    ByVal e As System.EventArgs) Handles Button1.Click
    Dim xwriter As New XmlTextWriter("data.xml", System.Text.Encoding.UTF8)

    xwriter.WriteStartDocument(True)


       xwriter.WriteStartElement("states", "www.XMLPowerCorp.com")


       xwriter.WriteStartElement("state", "www.XMLPowerCorp.com")
        .
        .
        .

Now write the child elements that contain the document's data, such as <name>, <population>, and so on. All these elements just contain text, so you can use the WriteElementString method to write them. Here's how to write the data for California:

xwriter.WriteElementString("name", "www.XMLPowerCorp.com", "California")
xwriter.WriteElementString("population", "www.XMLPowerCorp.com", "33871648")
xwriter.WriteElementString("capital", "www.XMLPowerCorp.com", "Sacramento")
xwriter.WriteElementString("bird", "www.XMLPowerCorp.com", "Quail")
xwriter.WriteElementString("flower", "www.XMLPowerCorp.com", "Golden Poppy")
xwriter.WriteElementString("area", "www.XMLPowerCorp.com", "155959")

Now end this first <state> element with the WriteEndElement method:

xwriter.WriteEndElement()

Here's how to write the data for the Massachusetts and New York <state> elements, and then close those elements, close the <states> element, and end the document:

    xwriter.WriteStartElement("state", "www.XMLPowerCorp.com")

    xwriter.WriteElementString("name", "www.XMLPowerCorp.com", "Massachusetts")
    xwriter.WriteElementString("population", "www.XMLPowerCorp.com", "6349097")
    xwriter.WriteElementString("capital", "www.XMLPowerCorp.com", "Boston")
    xwriter.WriteElementString("bird", "www.XMLPowerCorp.com", "Chickadee")
    xwriter.WriteElementString("flower", "www.XMLPowerCorp.com", "Mayflower")
    xwriter.WriteElementString("area", "www.XMLPowerCorp.com", "7840")

    xwriter.WriteEndElement()

    xwriter.WriteStartElement("state", "www.XMLPowerCorp.com")

    xwriter.WriteElementString("name", "www.XMLPowerCorp.com", "New York")
    xwriter.WriteElementString("population", "www.XMLPowerCorp.com",
        "18976457")
    xwriter.WriteElementString("capital", "www.XMLPowerCorp.com", "Albany")
    xwriter.WriteElementString("bird", "www.XMLPowerCorp.com", "Bluebird")
    xwriter.WriteElementString("flower", "www.XMLPowerCorp.com", "Rose")
    xwriter.WriteElementString("area", "www.XMLPowerCorp.com", "47214")

    xwriter.WriteEndElement()

    xwriter.WriteEndElement()
    xwriter.WriteEndDocument()

    xwriter.Close()
End Sub

That's all you need. When you run this example, you see our states data XML document stored in the project's bin directory as data.xml—this time created by Visual Basic .NET. Listing 21.1 shows this document.

Example 21.1. An XML Document (data.xml)

<?xml version="1.0" encoding="utf-8" standalone="yes"?>
<states xmlns="www.XMLPowerCorp.com">
    <state>
        <name>California</name>
        <population>33871648</population>
        <capital>Sacramento</capital>
        <bird>Quail</bird>
        <flower>Golden Poppy</flower>
        <area>155959</area>
    </state>

    <state>
        <name>Massachusetts</name>
        <population>6349097</population>
        <capital>Boston</capital>
        <bird>Chickadee</bird>
        <flower>Mayflower</flower>
        <area>7840</area>
    </state>

    <state>
        <name>New York</name>
        <population>18976457</population>
        <capital>Albany</capital>
        <bird>Bluebird</bird>
        <flower>Rose</flower>
        <area>47214</area>
    </state>
</states>

Now it's time to read this document back in.

Reading XML

You can read XML documents in with XmlTextReader objects, which work something like a SAX parser. You can create a new XmlTextReader object, xreader, that is tied to the Read XML Document button in the XML document, data.xml, like this:

Private Sub Button2_Click(ByVal sender As System.Object, _
    ByVal e As System.EventArgs) Handles Button2.Click
    Dim xreader As XmlTextReader = Nothing


       xreader = New XmlTextReader("data.xml")
        .
        .
        .

Now loop over all nodes in your document by using a While loop and the XmlTextReader class's Read method. Each time through the loop, check the current node's type by using the XmlTextReader object's NodeType property; if that property equals XmlNodeType.XmlDeclaration, the current node is an XML declaration, if it equals XmlNodeType.ProcessingInstruction, it's a processing instruction, and so on. You can format the actual data in the node for display by using a procedure named Format, which you'll call for every node type, like this:

Private Sub Button2_Click(ByVal sender As System.Object, _
    ByVal e As System.EventArgs) Handles Button2.Click
    Dim xreader As XmlTextReader = Nothing

    xreader = New XmlTextReader("data.xml")

    While xreader.Read()


           Select Case (xreader.NodeType)


               Case XmlNodeType.XmlDeclaration

                   Format(xreader, "XmlDeclaration")


               Case XmlNodeType.ProcessingInstruction

                   Format(xreader, "ProcessingInstruction")


               Case XmlNodeType.DocumentType

                   Format(xreader, "DocumentType")


               Case XmlNodeType.Comment

                   Format(xreader, "Comment")


               Case XmlNodeType.Element

                   Format(xreader, "Element")


               Case XmlNodeType.Text

                   Format(xreader, "Text")


               Case XmlNodeType.Whitespace

           End Select

       End While

End Sub

In this example, the Format procedure will format and display data from element and text nodes in your application's text box. To get the name of an element, use the XmlTextReader object's Name property, and to get the value of an element or text node, use the XmlTextReader object's Value property. Here's what this looks like in code:

Sub Format(ByRef reader As XmlTextReader, ByVal nodeType As String)
    If (nodeType = "Element") Then

           TextBox1.Text &= "<" & reader.Name & ">" & reader.Value & _

               ControlChars.CrLf

       End If


       If (nodeType = "Text") Then

           TextBox1.Text &= "    " & reader.Value & ControlChars.CrLf

       End If
End Sub

Now when the user clicks the Write XML Document button, your application will write the states data to data.xml. When the user clicks the Read XML Document button, the application will read that data back and display it, as shown in Figure 21.16.

Figure 21.16 Reading XML in Visual Basic .NET code.

Listing 21.2 shows the code we've written for this example.

Example 21.2. Writing and Reading XML in .NET (Form1.vb from the ch21_02 Project)

Imports System.Xml
        .
        .
        .
Private Sub Button1_Click(ByVal sender As System.Object, _
    ByVal e As System.EventArgs) Handles Button1.Click
    Dim xwriter As New XmlTextWriter("data.xml", System.Text.Encoding.UTF8)

    xwriter.WriteStartDocument(True)

    xwriter.WriteStartElement("states", "www.XMLPowerCorp.com")

    xwriter.WriteStartElement("state", "www.XMLPowerCorp.com")

    xwriter.WriteElementString("name", "www.XMLPowerCorp.com", "California")
    xwriter.WriteElementString("population", "www.XMLPowerCorp.com",
        "33871648")
    xwriter.WriteElementString("capital", "www.XMLPowerCorp.com", "Sacramento")
    xwriter.WriteElementString("bird", "www.XMLPowerCorp.com", "Quail")
    xwriter.WriteElementString("flower", "www.XMLPowerCorp.com",
        "Golden Poppy")
    xwriter.WriteElementString("area", "www.XMLPowerCorp.com", "155959")

    xwriter.WriteEndElement()

    xwriter.WriteStartElement("state", "www.XMLPowerCorp.com")

    xwriter.WriteElementString("name", "www.XMLPowerCorp.com", "Massachusetts")
    xwriter.WriteElementString("population", "www.XMLPowerCorp.com", "6349097")
    xwriter.WriteElementString("capital", "www.XMLPowerCorp.com", "Boston")
    xwriter.WriteElementString("bird", "www.XMLPowerCorp.com", "Chickadee")
    xwriter.WriteElementString("flower", "www.XMLPowerCorp.com", "Mayflower")
    xwriter.WriteElementString("area", "www.XMLPowerCorp.com", "7840")

    xwriter.WriteEndElement()

    xwriter.WriteStartElement("state", "www.XMLPowerCorp.com")

    xwriter.WriteElementString("name", "www.XMLPowerCorp.com", "New York")
    xwriter.WriteElementString("population", "www.XMLPowerCorp.com",
        "18976457")
    xwriter.WriteElementString("capital", "www.XMLPowerCorp.com", "Albany")
    xwriter.WriteElementString("bird", "www.XMLPowerCorp.com", "Bluebird")
    xwriter.WriteElementString("flower", "www.XMLPowerCorp.com", "Rose")
    xwriter.WriteElementString("area", "www.XMLPowerCorp.com", "47214")

    xwriter.WriteEndElement()

    xwriter.WriteEndElement()
    xwriter.WriteEndDocument()

    xwriter.Close()
End Sub

Private Sub Button2_Click(ByVal sender As System.Object, _
    ByVal e As System.EventArgs) Handles Button2.Click

    Dim xreader As XmlTextReader = Nothing

    xreader = New XmlTextReader("data.xml")

    While xreader.Read()

        Select Case (xreader.NodeType)

            Case XmlNodeType.XmlDeclaration
                Format(xreader, "XmlDeclaration")

            Case XmlNodeType.ProcessingInstruction
                Format(xreader, "ProcessingInstruction")

            Case XmlNodeType.DocumentType
                Format(xreader, "DocumentType")

            Case XmlNodeType.Comment
                Format(xreader, "Comment")

            Case XmlNodeType.Element
                Format(xreader, "Element")

            Case XmlNodeType.Text
                Format(xreader, "Text")

            Case XmlNodeType.Whitespace
        End Select
    End While

End Sub

Sub Format(ByRef reader As XmlTextReader, ByVal nodeType As String)
    If (nodeType = "Element") Then
        TextBox1.Text &= "<" & reader.Name & ">" & reader.Value &
        ControlChars.CrLf
    End If

    If (nodeType = "Text") Then
        TextBox1.Text &= "    " & reader.Value & ControlChars.CrLf
    End If
End Sub